Las Reliquias de Tolti Aph
An interactive fiction by Graham Nelson (2005) - the Inform 7 source text
Contents
Previous
Next
Complete text
Effect of casting escudo aéreo at:
record outcome "que forma un escudo casi invisible de forma circular sobre tu cabeza, que se mueve contigo";
now the player is affected by escudo aéreo;
rule succeeds.
A thing can be trapped or untrapped. A thing is usually not trapped.
Instead of drinking a trapped strength potion:
remove the noun from play;
say "Bebes [the noun], ¡pero está envenenada! Y te hace un daño de ";
let the extra be the roll of the additional strength of the noun;
decrease the strength of the player by the extra;
say " puntos de fuerza.";
if the player is killed, end the game saying "Has sido envenenado".
Instead of putting a trapped strength potion on a weapon:[1]
remove the noun from play;
let the hit power be the hit dice of the second noun;
let N be the dice part of the hit power;
let S be the sides part of the hit power;
let A be the adds part of the hit power;
increase A by 2;
increase N by 1;
change the hit dice of the second noun to the die roll with dice part N sides part S adds part A;
say "Cuidadosamente, aplicas el veneno contenido en [the noun] sobre [the second noun], gastándolo todo."
Understand "envenena [something]" as a mistake ("¿Cómo, exactamente?").
A person can be slumbering or wakeful.
Effect of casting dormir dragón at a wyvern:
if the second noun is wakeful
begin;
record outcome "y es suficiente para engañarle, pues el guiverno, aún no siendo un dragón, siempre se siente halagado por la sugerencia de contar como uno de los grandes esquemas de las cosas. Pronto se escuchan enormes ronquidos";
award 4 points;
now the second noun is slumbering;
otherwise;
record outcome "pero, después de todo, el wyvern está ya dormido";
end if;
rule succeeds.
Instead of doing something to a slumbering wyvern, say "Mejor dejar que la wyvern durmiente descanse."
Effect of casting detectar trampa at:
if a trapped thing is visible
begin;
record outcome "que da vueltas como un remolino a tu alrededor por un tiempo hasta que finalmente se posa sobre [the list of trapped visible things]. Sonríes maliciosamente";
otherwise;
record outcome "pero esta brilla momentáneamente hasta desaparecer con un sentimiento de calma y normalidad";
end if;
rule succeeds.
Effect of casting modelar vara at:
now the current spell focus is madera imbuida de magia;
record outcome "un calor abrasador crece en tus manos mientras la madera se transforma en un mágico híbrido, imbuido con su fuerza";
rule succeeds.
Effect of casting calor interior at:
record outcome "que te rodea con un sentimiento acogedor de bienestar";
now the player is affected by calor interior;
rule succeeds.
Effect of casting huesos de hierro at:
record outcome "que retornan y se introducen por tu piel, fortaleciendo todo tu cuerpo";
now the player is affected by huesos de hierro;
rule succeeds.
Effect of casting conocer naturaleza at:
if the second noun is a direction, record outcome "los cuales se pierden para nunca más volver";
otherwise record outcome "que hacen una suerte de reconocimiento trazando después la firma [la firma del the second noun] en mitad del aire";
rule succeeds.
[ * NT Lo anterior de "la firma del" es un saying, una frase construida para la ocasión para poder darle género a un kind of value (que no puede tener genero que valga por defecto, o sea, no hay manera humana en I7 de indicar que "carne" es femenino). La solución a este problema es cosa de Melitón. Con este mecanismo conseguimos que se imprima adecuadamente el "del papel" o "de la carne" según el material sea masculino o femenino.]
To say la firma del (object - a thing):
let mat be the material of the object;
if mat is papel or mat is metal or mat is sustento or mat is aire:
say "del";
otherwise:
say "de la";
say " [material of the second noun]"
Effect of casting luz mágica at:
record outcome "que baña la parte superior de tu cuerpo con luminiscencia";
now the player is affected by luz mágica;
now the player is lit;
rule succeeds.
Every turn: if the player is not affected by luz mágica, now the player is unlit.
Effect of casting misil mágico at something:
if the second noun is a person
begin;
record outcome "irrumpiendo en una explosión de fuego mágico";
record event the misil mágico strike rule;
otherwise;
if the second noun is portable and the second noun is not scenery
begin;
remove the second noun from play;
record outcome "que se vaporiza dejando tras de sí tan sólo un soplo de humo";
otherwise;
record outcome "que es sacudid[o the second noun] cuando absorbe el golpe, pero lo resiste";
end if;
end if;
rule succeeds.
This is the misil mágico strike rule:
say "Un misil mágico hace 1d6 de daño por nivel del hechicero, así que: ";
let L be the level of the player;
let the strike power be the die roll with dice part L sides part 6 adds part 0;
let the strike amount be the roll of the strike power;
say " puntos de daño";
now the second noun is hostile;
make the second noun take the strike amount points of damage.
Sanctum Sanctorum is a room. "Aquí en la calma, silencioso centro del mundo que gira, encuentras Santuario. Es un lugar para descansar, para meditar. A través de los nebulosos muros arcoiris, apenas puedes discernir [the room outside from the Sanctum Sanctorum], pero aparenta ser tan irreal como un sueño." Before going outside from the Sanctum Sanctorum, say "Parpadeas cuando tus ojos se ajustan a la aspereza de la realidad; la implacable vivacidad de la existencia."
The contornos arcoiris de tu santuario are fixed in place. "Ante ti están los contornos arcoiris de tu santuario, el cual sólo tú puedes ver, en el cual sólo tú puedes entrar." Instead of entering the contornos arcoiris: move the player to the Sanctum Sanctorum. [Understand "santuario" as the contornos arcoiris.]
Understand the command "dormir" as "duerme". [2] Understand the command "sueña" or "medita" as "duerme". Check sleeping (this is the can't sleep outside of sanctuary rule): if the location is not the Sanctum Sanctorum and the location is not the Templo de la Paz, say "Este no es un lugar seguro para recuperarse. Ningún sitio expuesto al ataque es lugar seguro." instead. Check sleeping: if the strength of the player is the permanent strength of the player, say "Estás sano y vigoroso, no hay necesidad de descansar." instead.
Include (-VerboIrregular "soñar" with imperativo 'sueña';-).
Carry out sleeping: restore the health of the player. Report sleeping: say "Descansas, absorbiendo toda la bondad curativa del santuario." Procedural rule: ignore the block sleeping rule.
Check saving the game: if the location is not the Sanctum Sanctorum and the location is not the Templo de la Paz, say "(El juego sólo puede ser salvado cuando se está en un lugar indiscutiblemente seguro. Este no es ese lugar. Lo reconocerás cuando lo encuentres.)" instead.[3]
Effect of casting hacer santuario at:
if the location is the Sanctum Sanctorum
begin;
record outcome "los cuales, menos mal, se dispipan inocentemente. Quizás haya necrománticos en el mundo que puedan escapar de un golpe como ese, pero tú no eres uno de ellos.";
rule succeeds;
end if;
record outcome "que crecen, tímidamente al principio pero con resolución hacia el final, hasta conformar ante ti los fantasmales límites de un santuario multicolor";
change the outside exit of the Sanctum Sanctorum to the location;
move the contornos arcoiris de tu santuario to the location;
rule succeeds.
Effect of casting memorizar at something:
record outcome "pero desaparece por si mismo, de una forma peculiarmente insatisfactoria";
rule succeeds.
Effect of casting memorizar at a scroll:
if the player is not carrying the second noun
begin;
record outcome "el cual, al no estar en tus manos, te tienta más de lo que revela";
rule succeeds;
end if;
remove the second noun from play;
now the player knows the inscribed spell of the second noun;
record outcome "el cual se desmorona en polvo, al tiempo que tu mente se llena con pensamientos sobre el hechizo [italic type][inscribed spell of the second noun][roman type]";
rule succeeds.
Effect of casting remendar at something:
record outcome "el cual casi imperceptible se endereza y se pone en orden, pero sin ningún efecto real";
rule succeeds.
Effect of casting remendar at a person:
record outcome "el cual palmea a [the second noun] en la cabeza, sin ningún beneficio práctico";
rule succeeds.
Definition: A person is undead if exorcizar no-muertos is its defensive charm.
This is the exorcizar no-muertos removal rule:
repeat with turned one running through the undead people in the location
begin;
remove the turned one from play;
award the permanent strength of the turned one points;
end repeat.
Effect of casting exorcizar no-muertos at:
if an undead person is in the location
begin;
record outcome "el cual, como una especie de lazo, rodea [the list of undead people in the location] y arrastra lo indeseado bajo tierra";
record event the exorcizar no-muertos removal rule;
rule succeeds;
end if;
record outcome "que lanza una especie de lazo sobre nada en particular, y entonces aprieta firmemente hasta desaparecer";
rule succeeds.
Effect of casting silencio at:
record outcome "es el silencio que se asienta amortiguadamente sobre tus pies";
now the player is affected by silencio;
rule succeeds.
Effect of casting invocar elemental at:
record outcome "mientras se escucha un horrendo sonido desgarrador proveniente de la misma tierra";
move Zoorl to the location;
now Zoorl is indifferent;
rule succeeds.
Effect of casting telaraña at a hostile monster:
record outcome "y las trenzas sedosas se visten alrededor de [the second noun], impidiendo todo movimiento";
now the second noun is affected by telaraña;
rule succeeds.
After printing the name of a person who is affected by telaraña when we are looking, say " (enredado)".
For calculating combat modifiers of a person who is affected by telaraña:
modify to-hit roll by -8 for "intentar luchar a través de la telaraña";
continue the activity.
Effect of casting telaraña at:
record outcome "pero las trenzas sedosas caen, indiferentes y sin sentido";
rule succeeds.
Notes
[1]. Esto no se le ocurrió al autor, de ninguna manera - uno de los testers lo intentó, y la idea parecía irresistible. Envenenar un arma añade todo un dado extra y un +2, así que es toda una recompensa para alguien lo suficientemente ingenioso para pensar en esto.